聖騎 macro 整理

==
攻擊最近目標 (tab 只會切換最近目標, t 只會攻擊目前目標, 而且再按一次就停止攻擊
#show Attack
#showtooltip Attack
/cleartarget
/targetenemy
/startattack [exists]
按一次就會選出離自己最近的目標開始攻擊, 連按也沒關係


==
使用第一格飾品 (這很單純)
#showtooltip 13
/use 13
第二格的同理, 換成 14


==
使用 BoF 後順便通知目標 (如果沒合法目標, casting hand 還是會出來讓你點目標, 當然這時候就無法通知了) (/tt 需要安裝 chatter 才有支援)
#showtooltip Blessing of Freedom
/cast Blessing of Freedom
/stopmacro [noexists][dead][nohelp]
/tt You got BoF!
BoP 同理, 改法術名稱就好了


==
如果有 focus, 對 focus 使用犧牲祝福. 如果沒有就對當前目標使用, 並順便將當前目標設為 focus (如果沒合法目標, casting hand 還是會出來讓你點目標, 當然這時候就無法順便設 focus) (犧牲祝福只能給隊友, 所以未組隊時整個 macro 關掉不反應) (macro 無法判斷目標是否為自己, 所以可能會將自己設為 focus, 這就沒辦法了)
#showtooltip Blessing of Sacrifice
/stopmacro [nogroup]
/cast [target=focus, help, nodead][] Blessing of Sacrifice
/stopmacro [target=focus, help, nodead]
/focus [help, nodead]


==
馬上開無敵 (中斷目前施法, 不過 GCD 還是無法中斷, 這點請注意) (end-game raid 搶這 0.5 秒常常就是生與死的差別, pvp 也是)
#showtooltip Divine Shield
/stopcasting
/cast Divine Shield


==
如果有 focus, 對 focus 使用懺悔. 如果沒有就對當前目標使用 (如果沒合法目標, casting hand 還是會出來讓你點目標)
#showtooltip Repentance
/cast [target=focus, harm, nodead][] Repentance


==
嘲諷 (已針對最近的 patch 修正過) (如果沒合法目標, casting hand 還是會出來讓你點目標)
#showtooltip Righteous Defense
/cast [noharm][target=targettarget, noharm][] Righteous Defense


==
Holy Joke 神聖笑話, 與 Divine Favor 同捆, 目標是敵人的時候順便開始 autoattack (如果沒合法目標, casting hand 還是會出來讓你點目標)
#showtooltip Holy Shock
/cast [combat] Divine Favor
/cast [help, nodead][harm, nodead][] Holy Shock
/startattack [harm, nodead]


==
FoL 小補, 順便換上小補專用書, 支援 spam 連發, 支援點 boss 補坦克. (如果沒合法目標, casting hand 還是會出來讓你點目標)
#showtooltip Flash of Light
/console Sound_EnableSFX 0
/cast [help][target=targettarget, help][] Flash of Light
/equip Blessed Book of Nagrand
/run UIErrorsFrame:Clear()
/console Sound_EnableSFX 1
字數不足了, 無法加上複雜的判斷式避開不該換書的情況 (無合法目標 -> casting hand 出來 -> 換書 -> 引發 GCD -> casting hand 被強制取消)


==
HL rank6 的小補, 按住 shift 施法會換上 +mp5 書, 平常是 -mana 書, 其餘同 FoL macro
#showtooltip Holy Light(Rank 6)
/console Sound_EnableSFX 0
/cast [help][target=targettarget, help][] Holy Light(Rank 6)
/equip [modifier:shift] Libram of Mending
/equip [nomodifier:shift] Libram of Absolute Truth
/console Sound_EnableSFX 1
字數不足把 /run UIErrorsFrame:Clear() 刪了. 其他 HL rank 寫法相同


==
HL 最大補, 與 Divine Illumination 同捆, 會換上 -mana 書, 其實同 FoL macro
#showtooltip Holy Light
/console Sound_EnableSFX 0
/cast [combat] Divine Illumination
/cast [help][target=targettarget, help][] Holy Light
/equip Libram of Absolute Truth
/run UIErrorsFrame:Clear()
/console Sound_EnableSFX 1
字數不足拿掉 shift 換 +mp5 書的部份, 反正我不會用大補開